home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Belgian Amiga Club - ADF Collection
/
BS1 part 05.zip
/
BS1 part 5
/
IM_3.adf
/
Exec
/
piarc.LZH
/
launch.rexx
< prev
next >
Wrap
OS/2 REXX Batch file
|
1992-02-29
|
3KB
|
99 lines
/*
* launch.rexx a P.I. module to launch another script using the
* image processor's list requester
*
*
* Written by: Barry Chalmers
* Last Update: March 3rd, 1992
* Revision: 1.01
* For: Black Belt Systems image processing series IM, IM F/c, and IP.
*/
parse arg firstarg ',' secondarg
/*
* open rexxsupport.library -- needed for some functions
*/
if ~show('L',"rexxsupport.library") then do
if addlib('rexxsupport.library',0,-30,0) then do
/* everything's ok */
end;
else do
say 'We Have A Library Problem, Unable To Load "rexxsupport.library"';
say 'Cannot operate RESOLVER.rexx without this library - sorry!';
exit 10;
end;
end;
/*
* This will automatically direct the script to the proper
* software, if it is running. No matter where the script is
* launched from. :^) I sure do like ARexx. :^))
*/
prtnme = 'IP_Port'; /* assume Image Professional */
if show('P','IP_Port') = 0 then do
if show('P','IM_Port') = 0 then do
say "Can't find image processor's ARexx port!!!"; /* not running? */
say "This script requires IP, IM or IM F/c to run!";
exit(20);
end;
else do
prtnme = 'IM_Port'; /* That's the thing about assumptions... */
end; /* We make em, user's break em. */
end;
/*
* This code attempts to read a file called "picmdpath" from REXX:
* If it can't find it, the script will assume that the commands
* associated with this PI Module are in "c:". If the file exists,
* the script will look in the path that is specified in the file.
* If you create this file, you MUST put a complete, correct path
* in it; if the commands are in a sub-directory, you have to put
* the trailing slash on the path (like, device:dir/).
*
*/
cmdpath = 'c:';
if open(fhandle,'rexx:picmdpath','read') then /* open the file */
do
cmdpath = readln(fhandle);
call close(fhandle); /* close the file */
end
address(prtnme);
prevgfunc = '';
if show('C',prefunk) = 1 then
do
prevgfunc = getclip(prefunk);
end;
if firstarg = '' then
do
'message "The Script Launcher requires a LIST name"';
end
options results
'listreq "Launch a P.I. Module","'||cmdpath||firstarg||'",'||secondarg
tname = result
options
if tname = '' then
do
exit 0;
end
name = "rxpi:"||tname /* Let the OS handle the .rexx extension */
parse var name rname ':' fname '.' ename
if ename = 'rexx' then
do
call setclip(prefunk,fname);
end
/*
* This should simply launch the requested script:
*/
address command 'rx '||name
exit 0;